97 lines
2.8 KiB
Kotlin
97 lines
2.8 KiB
Kotlin
val wiremockVersion = "3.12.0"
|
|
val postgresqlVersion = "42.7.11"
|
|
val springAiVersion by extra("2.0.0")
|
|
|
|
plugins {
|
|
java
|
|
jacoco
|
|
id("org.springframework.boot") version "4.1.0"
|
|
id("io.spring.dependency-management") version "1.1.7"
|
|
id("org.sonarqube") version "7.3.0.8198"
|
|
}
|
|
|
|
group = "com.vaessl"
|
|
version = "0.0.1-SNAPSHOT"
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion = JavaLanguageVersion.of(25)
|
|
}
|
|
}
|
|
|
|
sonar {
|
|
properties {
|
|
property("sonar.projectKey", "Vaessl")
|
|
property("sonar.projectName", "Vaessl")
|
|
property("sonar.coverage.jacoco.xmlReportPaths",
|
|
"${layout.buildDirectory.get()}/reports/jacoco/test/jacocoTestReport.xml")
|
|
}
|
|
}
|
|
|
|
configurations {
|
|
compileOnly {
|
|
extendsFrom(configurations.annotationProcessor.get())
|
|
}
|
|
}
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
}
|
|
|
|
dependencyManagement {
|
|
imports {
|
|
mavenBom("org.springframework.ai:spring-ai-bom:$springAiVersion")
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
// Spring Boot Starters
|
|
implementation("org.springframework.boot:spring-boot-starter-data-jpa")
|
|
implementation("org.springframework.boot:spring-boot-starter-session-jdbc")
|
|
implementation("org.springframework.boot:spring-boot-starter-validation")
|
|
implementation("org.springframework.boot:spring-boot-starter-webmvc")
|
|
|
|
// Spring AI Starters (versions managed by spring-ai-bom)
|
|
implementation("org.springframework.ai:spring-ai-starter-model-openai")
|
|
implementation("org.springframework.ai:spring-ai-starter-vector-store-pgvector")
|
|
|
|
// Database
|
|
implementation("org.postgresql:postgresql:$postgresqlVersion")
|
|
|
|
// Tooling & Code Generation
|
|
compileOnly("org.projectlombok:lombok")
|
|
annotationProcessor("org.projectlombok:lombok")
|
|
developmentOnly("org.springframework.boot:spring-boot-devtools")
|
|
|
|
// Testing
|
|
testImplementation("org.springframework.boot:spring-boot-starter-data-jpa-test")
|
|
testImplementation("org.springframework.boot:spring-boot-starter-validation-test")
|
|
testImplementation("org.springframework.boot:spring-boot-starter-webmvc-test")
|
|
testImplementation("org.springframework.boot:spring-boot-starter-session-jdbc-test")
|
|
testImplementation("org.wiremock:wiremock-standalone:$wiremockVersion")
|
|
|
|
testRuntimeOnly("org.junit.platform:junit-platform-launcher")
|
|
}
|
|
|
|
tasks.withType<JavaCompile> {
|
|
options.compilerArgs.add("-parameters")
|
|
}
|
|
|
|
tasks.withType<Test> {
|
|
useJUnitPlatform()
|
|
finalizedBy(tasks.jacocoTestReport)
|
|
testLogging {
|
|
events("failed", "standardError")
|
|
exceptionFormat = org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL
|
|
showExceptions = true
|
|
showCauses = true
|
|
showStackTraces = true
|
|
}
|
|
}
|
|
|
|
tasks.jacocoTestReport {
|
|
dependsOn(tasks.withType<Test>())
|
|
reports {
|
|
xml.required = true
|
|
}
|
|
} |